         .OUTPI ALFRES
         .ENTRY LOCARG,CPYARG
         .VIRT8 ZPAG
;Chkbatch looks for the prompt and whatnot on the sparta command line
;
LOCARG   LDA $0A                ;POINT TO COMMAND LINE
         CLC
         ADC #63
         STA ZPAG
         LDA $0B
         ADC #0
         STA ZPAG+1
         LDA $0700
         CMP #$53    ;Sparta 3.2 ?
         BNE LOC002
         LDY OLDARG
         LDX #0
LOC001   LDA (ZPAG),Y
         CMP #32
         BEQ LOC003
         CMP #$9B    ;End of line ?
         BEQ LOC002
         INY
         CPY #64
         BCC LOC001
LOC002   SEC
         RTS         ;Not a batch file
LOC003   LDA (ZPAG),Y
         CMP #$9B
         BEQ LOC002
         CMP #32
         BNE LOC004
         INY
         CPY #64
         BCC LOC003
         BCS LOC002
LOC004   STY OLDARG
         CLC
         RTS

CPYARG   LDY OLDARG
         LDX #0
COPY1    LDA (ZPAG),Y
         STA LINE,X
         CMP #32
         BEQ COPY2
         CMP #$9B
         BEQ COPY2
         INX
         INY
         CPY #64
         BCC COPY1
COPY2    STX LINEL
         CLC
         RTS
