     .OUTPI ALFRES
     .ENTRY FQUAL,FXTN


;Filename qualifier, add .ALF and
;make default D1:
;
;Requires LINE to have the filename
;
FQUAL    LDA LINE
         CMP #"D"
         BNE FADRV   ;Go add drive
         LDA #":"
         CMP LINE+1
         BEQ FQXIT
         CMP LINE+2
         BEQ FQXIT
FADRV    LDA LINEL
         TAX 
         CLC 
         ADC #3
         STA LINEL
         TAY 
FQ01     LDA LINE,X
         STA LINE,Y
         DEY 
         DEX 
         BPL FQ01
         LDA #"D"
         LDX #"1"
         LDY #":"
         STA LINE
         STX LINE+1
         STY LINE+2
FQXIT    RTS 
;
;Add the Extension
;
ALFEXT   .BYTE ".ALF",$9B
FXTN     LDX LINEL
         DEX          Below the EOL
         LDY #0
FXT001   LDA LINE,X
         CMP #"."
         BEQ FXT002
         INY 
         DEX 
         BPL FXT001
         LDX LINEL
         BNE FXTADD  ;Not there so add it
FXT002   CPY #0      ;Is it *.
         BNE FXTXIT  ;Nope, so leave alone
FXTADD   LDY #0
FXT003   LDA ALFEXT,Y
         STA LINE,X
         INX 
         INY 
         CPY #5
         BCC FXT003
         DEX 
         STX LINEL
FXTXIT   RTS 
